' Prices and contanst price components of output
' Endogenous inflation

' creates a workfile for undated time series
WFCREATE(wf=model3) U 1 300
' generates model variables
SERIES K=1000
k.label(d) Stock of capital
SERIES M=200
m.label(d) Stock of deposits
SERIES L=M
l.label(d) Stock of loans
SERIES AZ=K-L
az.label(d) Stock of equities
SERIES VH=AZ+M
vh.label(d) Stock of household wealth
SERIES I = 95
i.label(d) Investment
SERIES PARZ = 0.1
' Note that parz is lower than in model 2
parz.label(d) Share of investment financed by issuing equities
SERIES DAZ = PARZ*I
daz.label(d) Flow of new equities

SERIES RM=0.01
rm.label(d) Interest rate on deposits
SERIES RL = 0.02
rl.label(d) Interest rate on loans
SERIES Y = 1000
y.label(d) GDP
SERIES CONS=Y-I
cons.label(d) Consumption
SERIES WB=0.9*Y
wb.label(d) Wage bill
SERIES FT=Y-WB
ft.label(d) Gross profits
SERIES PARD = 0.3
pard.label(d) Share of distributed profits
SERIES FD = PARD*(FT-RL*L)
fd.label(d) Dividends
SERIES FU = FT-FD-RL*L
fu.label(d) Undistributed profits
SERIES FB=RL*L-RM*M
fb.label(d) Bank profits
SERIES YF=WB+FD+RM*M+FB
yf.label(d) Disposable income of households
SERIES SH=YF-CONS
sh.label(d) Saving of households

SERIES PARC1 = 0.9
parc1.label(d) Propensity to consume out of income
SERIES PARC2 = 0.05
parc2.label(d) Propensity to consume out of wealth
SERIES PARW = 0.9
parw.label(d) Share of wages on income 
SERIES PARK = 0.0475
park.label(d) Depreciation rate

SERIES G=0.02
g.label(d) Growth rate of investment

series vf = k-az-l
vf.label(d) Net worth of firms
series parb = 2
parb.label(d) Mark-up on interest rate

Series DIVE = FD
dive.label(d) Expected dividends
SERIES PARA = 0.4
para.label(d) Speed of adjustment of expectations
SERIES PAZ = 1
paz.label(d) Price of equities
SERIES PAZE = PAZ
paze.label(d) Expected price of equities
SERIES RAZ = (DIVE+(PAZE-PAZ)*AZ)/AZ
raz.label(d) Rate of return on equities
SERIES PARP0 = 0.8
parp0.label(d) Parameter in portfolio equation
SERIES PARP1 = -0.5
parp1.label(d) Parameter in portfolio equation
SERIES PARP2 = 1
parp2.label(d) Parameter in portfolio equation
SERIES PARP3 = -0.5
parp3.label(d) Parameter in portfolio equation
SERIES SHOCKPAZ=0
shockpaz.label(d) Exogenous shock to equity prices
SERIES VHE = VH
vhe.label(d) Expected wealth
series gvh=0.02
gvh.label(d) Growth rate in household wealth

' Additional variables
series u=k/y
u.label(d) Capital-output ratio
Series parg0 = 0.045
parg0.label(d) Parameter in the investment function
Series parg1 = -0.005
parg1.label(d) Parameter in the investment function
Series parg2 = -0.25
parg2.label(d) Parameter in the investment function
Series parg3 = -0.025
parg3.label(d) Parameter in the investment function

Series prod=1
prod.label(d) Productivity
Series YK = Y
yk.label(d) GDP at constant prices
Series N = YK/prod
n.label(d) Employment
Series wage = 0.9
wage.label(d) Unit wages
Series parmu = 1/0.9-1
parmu.label(d) Mark-up
Series p = 1
p.label(d) Price level
series consk=cons
consk.label(d) Consumption at constant prices
series ik=i
ik.label(d) Investment at constant prices
series kk=k
kk.label(d) Stock of capital at constant prices
Series gprod = 0.019
gprod.label(d) Rate of growth in productivity
Series gwage = 0.019
gwage.label(d) Rate of growth in wages
Series tdis= 0.05
tdis.label(d) Unemployment rate
Series LF = 1.3*N/0.95
lf.label(d) Labour force
Series gpop = 0.00019
gpop.label(d) Rate of growth in population
Series dis=lf-n
dis.label(d) Unemployment

series infl=0
infl.label(d) Inflation rate
series infle=0
infle.label(d) Expected inflation rate
series pargw0 = 0.001
pargw0.label(d) Parameter in wage equation

MODEL mms3
mms3.APPEND Yk=CONSk+Ik
mms3.append Y = yk*p
mms3.append CONS = CONSK*p
mms3.append I = IK*p
mms3.APPEND YF=WB+FD+RM*M(-1)+FB
mms3.APPEND CONSk = PARC1*YF/p + PARC2*VH(-1)/p
mms3.APPEND WB = wage*N
mms3.APPEND FT = Y-WB
mms3.APPEND FD = PARD*(FT-RL*L(-1))
mms3.APPEND FU = FT - FD - RL*L(-1)
mms3.APPEND FB = RL*L(-1) - RM*M(-1)
mms3.APPEND SH = YF - CONS
mms3.APPEND Kk = Kk(-1)*(1-PARK) + Ik
mms3.append k=kk*p
mms3.APPEND DAZ = PARZ*I/PAZ
mms3.APPEND AZ = AZ(-1) + DAZ
mms3.APPEND L = L(-1) + I - FU - DAZ*paz
mms3.APPEND VH = VH(-1) + SH + (PAZ-PAZ(-1))*AZ(-1)
mms3.APPEND M = M(-1) + SH - PAZ*DAZ
mms3.APPEND Ik=Ik(-1)*(1+G)
mms3.APPEND vf = k-PAZ*az-l
mms3.append rl = rm*parb
mms3.APPEND DIVE = FD(-1)+PARA*(FD(-1)-DIVE(-1))
mms3.APPEND PAZE = PAZ(-1)+PARA*(PAZ(-1)-PAZE(-1))+SHOCKPAZ
mms3.APPEND RAZ = (DIVE+(PAZE-PAZ)*AZ(-1))/(PAZ(-1)*AZ(-1))
mms3.append PAZ  = (((PARP0  + PARP1  * RM  + PARP3  * YF  / VHe)  * VHe)  + PARP2 * ((DIVE  + PAZE  * AZ(-1))  / (PAZ (-1) * AZ(-1))) * VHe  - PARZ * I) / (AZ(-1)  + PARP2 * VHe / PAZ(-1))
'mms3.APPEND PAZ = (PARP0+PARP1*RM+PARP2*RAZ+PARP3*YF/VHe)*VHe/AZ
mms3.APPEND VHE = VH(-1)*(1+gvh(-1))
mms3.append gvh=vh/vh(-1)-1
mms3.append u=K/Y
mms3.append g = parg0 + parg1*u(-1) + parg2*rl + parg3*l(-1)/k(-1)
mms3.append N = YK/prod
mms3.append P = wage*(1+parmu)/prod
mms3.append prod = prod(-1)*(1 + gprod)
mms3.append wage = wage(-1)*(1 + gwage)
mms3.append lf = lf(-1)*(1 + gpop)
mms3.append tdis = (lf - n)/lf
mms3.append infl = p/p(-1)-1
mms3.append infle = infl(-1)+para*(infl(-1)-infle(-1))
mms3.append gwage = pargw0-0.01*tdis+0.75*infle+gprod


SMPL 2 @last
mms3.SCENARIO "Baseline"
mms3.SOLVE

mms3.scenario "Scenario 1"
'copy gprod gprod_1
copy rm rm_1
mms3.override rm

smpl 100 @last
'gprod_1 = gprod_1 - 0.005
rm_1 = rm_1 + 0.01
smpl 2 @last
mms3.solve