' Portfolio choice between equities and deposits, based on expected wealth
' better specification for expected wealth

' creates a workfile for undated time series
WFCREATE(wf=model2) U 1 300
' generates model variables
SERIES K=1000
k.label(d) Stock of capital
SERIES M=200
m.label(d) Stock of deposits
SERIES L=M
l.label(d) Stock of loans
SERIES AZ=K-L
az.label(d) Stock of equities
SERIES VH=AZ+M
vh.label(d) Stock of household wealth
SERIES I = 95
i.label(d) Investment
SERIES PARZ = 0.2
parz.label(d) Share of investment financed by issuing equities
SERIES DAZ = PARZ*I
daz.label(d) Flow of new equities

SERIES RM=0.01
rm.label(d) Interest rate on deposits
SERIES RL = 0.02
rl.label(d) Interest rate on loans
SERIES Y = 1000
y.label(d) GDP
SERIES CONS=Y-I
cons.label(d) Consumption
SERIES WB=0.9*Y
wb.label(d) Wage bill
SERIES FT=Y-WB
ft.label(d) Gross profits
SERIES PARD = 0.3
pard.label(d) Share of distributed profits
SERIES FD = PARD*(FT-RL*L)
fd.label(d) Dividends
SERIES FU = FT-FD-RL*L
fu.label(d) Undistributed profits
SERIES FB=RL*L-RM*M
fb.label(d) Bank profits
SERIES YF=WB+FD+RM*M+FB
yf.label(d) Disposable income of households
SERIES SH=YF-CONS
sh.label(d) Saving of households


SERIES PARC1 = 0.9
parc1.label(d) Propensity to consume out of income
SERIES PARC2 = 0.05
parc2.label(d) Propensity to consume out of wealth
SERIES PARW = 0.9
parw.label(d) Share of wages on income 
SERIES PARK = 0.0475
park.label(d) Depreciation rate
' Note park is lower than in model 1

SERIES G=0.02
g.label(d) Growth rate of investment

' Additional variables
series vf = k-az-l
vf.label(d) Net worth of firms
series parb = 2
parb.label(d) Mark-up on interest rate

Series DIVE = FD
dive.label(d) Expected dividends
SERIES PARA = 0.4
para.label(d) Speed of adjustment of expectations
SERIES PAZ = 1
paz.label(d) Price of equities
SERIES PAZE = PAZ
paze.label(d) Expected price of equities
SERIES RAZ = (DIVE+(PAZE-PAZ)*AZ)/AZ
raz.label(d) Rate of return on equities
SERIES PARP0 = 0.8
parp0.label(d) Parameter in portfolio equation
SERIES PARP1 = -0.5
parp1.label(d) Parameter in portfolio equation
SERIES PARP2 = 1
parp2.label(d) Parameter in portfolio equation
SERIES PARP3 = -0.5
parp3.label(d) Parameter in portfolio equation
SERIES SHOCKPAZ=0
shockpaz.label(d) Exogenous shock to equity prices
SERIES VHE = VH
vhe.label(d) Expected wealth
series gvh=0.02
gvh.label(d) Growth rate in household wealth

MODEL mss2
mss2.APPEND Y=CONS+I
mss2.APPEND YF=WB+FD+RM*M(-1)+FB
mss2.APPEND CONS = PARC1*YF + PARC2*VH(-1)
mss2.APPEND WB = PARW*Y
mss2.APPEND FT = Y-WB
mss2.APPEND FD = PARD*(FT-RL*L(-1))
mss2.APPEND FU = FT - FD - RL*L(-1)
mss2.APPEND FB = RL*L(-1) - RM*M(-1)
mss2.APPEND SH = YF - CONS
mss2.APPEND K = K(-1)*(1-PARK) + I
mss2.APPEND DAZ = PARZ*I/PAZ
mss2.APPEND AZ = AZ(-1) + DAZ
mss2.APPEND L = L(-1) + I - FU - DAZ*paz
mss2.APPEND VH = VH(-1) + SH + (PAZ-PAZ(-1))*AZ(-1)
mss2.APPEND M = M(-1) + SH - PAZ*DAZ
mss2.APPEND I=I(-1)*(1+G)
mss2.APPEND vf = k-PAZ*az-l
mss2.append rl = rm*parb
mss2.APPEND DIVE = FD(-1)+PARA*(FD(-1)-DIVE(-1))
mss2.APPEND PAZE = PAZ(-1)+PARA*(PAZ(-1)-PAZE(-1))+SHOCKPAZ
mss2.APPEND RAZ = (DIVE+(PAZE-PAZ)*AZ(-1))/(PAZ(-1)*AZ(-1))
mss2.APPEND PAZ = (PARP0+PARP1*RM+PARP2*RAZ+PARP3*YF/VHe)*VHe/AZ
mss2.APPEND VHE = VH(-1)*(1+gvh(-1))
mss2.append gvh=vh/vh(-1)-1

SMPL 2 300
mss2.SCENARIO "Baseline"
mss2.SOLVE

stop
SMPL 151 @LAST
PARD = 0.5
SMPL 2 @LAST
mss2.SCENARIO "Scenario 1"
mss2.SOLVE