' A simple model, with exogenous income distribution

' creates a workfile for undated time series
WFCREATE(wf=model1) U 1 300
' generates model variables
SERIES K=1000
k.label(d) Stock of capital
SERIES M=200
m.label(d) Stock of deposits
SERIES L=M
l.label(d) Stock of loans
SERIES AZ=K-L
az.label(d) Stock of equities
SERIES VH=AZ+M
vh.label(d) Stock of household wealth
SERIES I = 95
i.label(d) Investment
' Parz: share of investment financed by issuing equities
SERIES PARZ = 0.2
parz.label(d) Share of investment financed by issuing equities
SERIES DAZ = PARZ*I
daz.label(d) Flow of new equities

SERIES RM=0.01
rm.label(d) Interest rate on deposits
SERIES RL = 0.02
rl.label(d) Interest rate on loans
SERIES Y = 1000
y.label(d) GDP
SERIES CONS=Y-I
cons.label(d) Consumption
SERIES WB=0.9*Y
wb.label(d) Wage bill
SERIES FT=Y-WB
ft.label(d) Gross profits
SERIES PARD = 0.3
pard.label(d) Share of distributed profits
SERIES FD = PARD*(FT-RL*L)
fd.label(d) Dividends
SERIES FU = FT-FD-RL*L
fu.label(d) Undistributed profits
SERIES FB=RL*L-RM*M
fb.label(d) Bank profits
SERIES YF=WB+FD+RM*M+FB
yf.label(d) Disposable income of households
SERIES SH=YF-CONS
sh.label(d) Saving of households

SERIES PARC1 = 0.9
parc1.label(d) Propensity to consume out of income
SERIES PARC2 = 0.05
parc2.label(d) Propensity to consume out of wealth
SERIES PARW = 0.9
parw.label(d) Share of wages on income 
SERIES PARK = 0.2
park.label(d) Depreciation rate

SERIES G=0.02
g.label(d) Growth rate of investment

MODEL mss
mss.APPEND Y=CONS+I
mss.APPEND YF=WB+FD+RM*M(-1)+FB
mss.APPEND CONS = PARC1*YF + PARC2*VH(-1)
mss.APPEND WB = PARW*Y
mss.APPEND FT = Y-WB
mss.APPEND FD = PARD*(FT-RL*L(-1))
mss.APPEND FU = FT - FD - RL*L(-1)
mss.APPEND FB = RL*L(-1) - RM*M(-1)
mss.APPEND SH = YF - CONS
mss.APPEND K = K(-1)*(1-PARK) + I
mss.APPEND DAZ = PARZ*I
mss.APPEND AZ = AZ(-1) + DAZ
mss.APPEND L = L(-1) + I - FU - DAZ
mss.APPEND VH = VH(-1) + SH
mss.APPEND M = M(-1) + SH - DAZ
mss.APPEND I=I(-1)*(1+G)

SMPL 2 300
mss.SCENARIO "Baseline"
mss.SOLVE