' next command creates the workfile
wfcreate u 1 300

SERIES PARK = 0.2
series i = 200
i.label(d) = Investment
series k = I/PARK
SERIES PARW = 0.75
SERIES PARD = 0.2
series rl = 0.03
rl.label(d) Interest rate on loans
series rm = 0.02
rm.label(d) Interest rate on deposits
series y=i/((1-PARD)*(1-PARW))
series YH = (PARW+PARD*(1-PARW))*Y
YH.label(d) Income of households
series PARC1=0.875
parc1.label(d) propensity to consume out of income
series parc2 = 0.1
parc2.label(d) propensity to consume out of wealth
series VH=(1-parc1)*YH/parc2
VH.label(d) Wealth of household

series eq = 0.5*vh
eq.label(d) Stock of equities
series L = k-eq
series M = L
M.LABEL(D) Stock of deposits
SERIES VF = K  - L - EQ
VF.label(d) FIRMS Net wealth
series cons = parc1*yh+parc2*vh
cons.label(d) Consumption
series wb=parw*y
wb.label(d) Wage bill
series ft = y - wb
ft.label(d) Profits
series fd = pard*ft
fd.label(d) Dividends
series fb = 0
fb.label(d) Banks profits (distributed as dividends)
series SH = YH - CONS
SH.label(d) Saving of households
series fu = ft - fd - rl*L
fu.label(d) Undistributed profits (retained earnings)

SERIES PARZ = 0.1
series g = 0.03
g.label(d) growth rate of investment

MODEL SFC1
SFC1.APPEND M = VH - EQ
SFC1.APPEND VF = K - L - EQ
SFC1.APPEND Y = CONS + I
SFC1.APPEND WB = PARW*Y
SFC1.APPEND FT = Y - WB
SFC1.APPEND YH = wb + fd + rm*m(-1) + fb
SFC1.APPEND SH = YH - CONS
SFC1.APPEND FU = FT - FD - RL*L(-1)
SFC1.APPEND FD = PARD*FT
SFC1.APPEND FB = RL*L(-1) - RM*M(-1)
SFC1.APPEND EQ = EQ(-1) + PARZ*(I-FU)
SFC1.APPEND L = L(-1) + I - FU - (EQ-EQ(-1))
SFC1.APPEND VH = VH(-1) + SH
SFC1.APPEND K = K(-1)*(1-PARK) + I
SFC1.APPEND CONS = PARC1*YH + PARC2*VH(-1)
sfc1.append I = I(-1)*(1+g)
SFC1.APPEND G = 0.04-0.01*L(-1)/K(-1)-0.005*K(-1)/Y(-1)

SFC1.SOLVE