' next command creates the workfile
wfcreate u 1 300

' Next commands create time series for the given sample
series y=1000
y.label(d) Output
series k = y
k.label(d) Stock of capital
series eq = 0.8*k
eq.label(d) Stock of equities
series L = 0.2*k
L.label(d) Stock of loans
series M = L
M.LABEL(D) Stock of deposits
SERIES VH = EQ + M
VH.LABEL(D) Household wealth
SERIES VF = K  - L - EQ
VF.label(d) FIRMS Net wealth
series i = 200
i.label(d) = Investment
series cons = 800
cons.label(d) Consumption
series wb=900
wb.label(d) Wage bill
series ft = y - wb
ft.label(d) Profits
series rm = 0.02
rm.label(d) Interest rate on deposits
series fd = 30
fd.label(d) Dividends
series fb = 2
fb.label(d) Banks profits (distributed as dividends)
series YH = wb + fd + rm*m + fb
YH.label(d) Income of households
series SH = YH - CONS
SH.label(d) Saving of households
series rl = 0.03
rl.label(d) Interest rate on loans
series fu = ft - fd - rl*L
fu.label(d) Undistributed profits (retained earnings)

SERIES PARW = 0.9
parw.label(d) Share of wages on output
SERIES PARD = 0.3
pard.label(d) Share of distributed profits
SERIES PARZ = 0.1
parz.label(d) Share of investment financed by issuing equities
SERIES PARK = 0.0475
park.label(d) Depreciation rate

' Next command creates a model object named SFC1
MODEL SFC1
' Next lines add equations to the model
SFC1.APPEND M = VH - EQ
SFC1.APPEND VF = K - L - EQ
SFC1.APPEND Y = CONS + I
SFC1.APPEND WB = PARW*Y
SFC1.APPEND FT = Y - WB
SFC1.APPEND YH = wb + fd + rm*m(-1) + fb
SFC1.APPEND SH = YH - CONS
SFC1.APPEND FU = FT - FD - RL*L(-1)
SFC1.APPEND FD = PARD*FT
SFC1.APPEND FB = RL*L(-1) - RM*M(-1)
SFC1.APPEND EQ = EQ(-1) + PARZ*I
SFC1.APPEND L = L(-1) + I - FU - (EQ-EQ(-1))
SFC1.APPEND VH = VH(-1) + SH
SFC1.APPEND K = K(-1)*(1-PARK) + I
SFC1.APPEND CONS = 1.2+0.8*YH + 0.05*VH(-1)

'Next line will solve the model for the current sample
sfc1.solve